редакция на best player of the round плъгин

[bgzone]

Здравейте имам плъгин в момента , който изписва най добрия играч на рунда по средата. Проблема с него е това, че си съвпадат по позиция със Counter Terrorist Win или Terrorist Win и не се вижда много добре. Можете ли да го изместите малк нагоре така , че да не си пречат ( или ако има вариант да скрия CT Win / T win ? ) благодаря

Code: Select all

#include <amxmodx>  
#include <amxmisc>  
#include <hamsandwich>
#include <cstrike>

new g_iKills[33],
    g_iHS[33],
    Float:g_fDmg[33]  

public plugin_init()  
{  
    register_plugin("Player of the Round", "1.0", "OciXCrom @ forum.iPlay.bg")  
    RegisterHam(Ham_TakeDamage, "player", "OnTakeDamage")  
    register_event("DeathMsg", "OnPlayerKilled", "a")  
    register_logevent("OnRoundEnd", 2, "1=Round_End")  
}  

public client_disconnect(id)  
{  
    g_iKills[id] = 0 
    g_iHS[id] = 0
    g_fDmg[id] = 0.0
}

public OnTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits)  
{  
    if(is_user_connected(iAttacker) && iAttacker != iVictim && is_user_connected(iVictim))
    {
        if(cs_get_user_team(iAttacker) != cs_get_user_team(iVictim))  
            g_fDmg[iAttacker] += fDamage
        else  
            g_fDmg[iAttacker] -= fDamage
    }
}

public OnPlayerKilled()
{  
    new iAttacker = read_data(1), iVictim = read_data(2)  
      
    if(is_user_connected(iAttacker) && iAttacker != iVictim && is_user_connected(iVictim))
    {
        if(cs_get_user_team(iAttacker) != cs_get_user_team(iVictim))
        {
            g_iKills[iAttacker]++
            
            if(read_data(3))
                g_iHS[iAttacker]++
        }
        else
        {
            g_iKills[iAttacker]--
            
            if(read_data(3))
                g_iHS[iAttacker]--
        }
    }
}

public OnRoundEnd()
{
    new id = get_best_player()
    
    if(id == -1)
        return
        
    new szName[32]  
    get_user_name(id, szName, charsmax(szName)) 

    set_hudmessage(.holdtime = 5.0)
    show_hudmessage(0, "The best player of the round is %s )", szName)
    
    arrayset(g_iKills, 0, sizeof(g_iKills))
    arrayset(g_iHS, 0, sizeof(g_iHS))
    
    for(new i; i < sizeof(g_fDmg); i++)
        g_fDmg[i] = 0.0
}

get_best_player()
{
    new iPlayers[32], iPnum, id
    get_players(iPlayers, iPnum)
    
    for(new i, iPlayer; i < iPnum; i++)
    {
        iPlayer = iPlayers[i]
        
        if(g_iKills[iPlayer] > g_iKills[id])
            id = iPlayer
        else if(g_iKills[iPlayer] == g_iKills[id])
        {
            if(g_fDmg[iPlayer] > g_fDmg[id])
                id = iPlayer
        }
    }
    
    return g_iKills[id] ? id : -1
}